身為財務會計，每天都要跟很多公式打交道，會涉及到各種各樣的問題。今天，盧子為你整理了9條最常用的公式。

1.將借方、貸方金額分離的簡單辦法

借方金額，在C2輸入公式，并向下填充。

=IF(A2="借",B2,"")

貸方金額，在D2輸入公式，并向下填充。

=IF(A2="貸",B2,"")

2.將一級科目篩選出來，也就是科目代碼為4位數(shù)。

有2種比較常用的方法：

01 用LEN函數(shù)判斷位數(shù)，然后篩選TRUE。

=LEN(A2)=4

02 通過搜索框，輸入????（4個？）也可以實現(xiàn)。

3.將一級科目放在一列，其他級別科目放在另一列。

一級科目：

=IF(LEN(A2)=4,B2,"")

其他級別科目：

=IF(LEN(A2)<>4,B2,"")

都是借助LEN判斷是不是等于4位數(shù)，從而進行分離科目。

4.科目從一級到四級都有，如何提取最后一級科目？

最后一級科目，用Excel的語言就是最后一個文本。查找對應值，當然用查找之王LOOKUP函數(shù)。

在F2輸入公式，下拉填充公式。

=LOOKUP("座",B2:E2)

當有多個符合條件的值存在，LOOKUP函數(shù)是查詢最后一個滿足條件的值?，F(xiàn)在，盧子舉一個小例子進行說明，因為漢字不太直觀，這里換成字母。

Z是最大的字母，所有字母都小于等于他。如第3行，有D和C，這兩個字母都比Z小，就返回最后一個值C。如第5行，C、B、A、F都比Z小，就返回最后一個值F。記住，這里是返回最后一個滿足條件的字母，而不是最大的字母。

文本都是按字母排序，而座（ZUO)的首字母是Z，通常情況下的漢字都比座小，利用這個特點可以找到最后一個文本，也就是最后一個科目。

更多LOOKUP函數(shù)的用法，詳見文章《VLOOKUP函數(shù)滾一邊去，我才是Excel真正的查找之王！》

科目還有一種比較常用的方法，就是以-作為分隔符號，這種情況，又該如何提取最后一級科目呢？

如果你函數(shù)玩得出神入化，可以用函數(shù)搞定。

=TRIM(RIGHT(SUBSTITUTE(B2,"-",REPT(" ",50)),50))

新函數(shù)：

=TEXTAFTER(B2,"-",-1,,,B2)

不過，這里盧子要教你一種簡單的辦法——替換法。

將B列的科目復制到C列，按Ctrl+H調出查找和替換對話框，查找內容輸入*-，單擊全部替換。

*-意思就是將-和之前的所有內容替換掉，剩下的就是最后的科目。

5.如果科目不是文本，是數(shù)字的情況下，如何提取最后一級科目？

現(xiàn)在我們將科目都換成了數(shù)字，文本我們用"座"來查找，數(shù)字就用9E+307來查找。

=LOOKUP(9E+307,A2:D2)

通用公式，不管是數(shù)字還是文本，都可以。

=LOOKUP(1,0/(A2:D2<>""),A2:D2)

6.如何提取第一級科目？

LOOKUP函數(shù)有兩個兄弟，一個是非常出名的VLOOKUP函數(shù)，另一個是HLOOKUP函數(shù)。HLOOKUP函數(shù)的用武之地很少，知道他存在的人并不多。

這里，剛好是一個特例。

=HLOOKUP("*",A2:D2,1,0)

"*"我們知道這個是通配符，在這里代表所有文本，而HLOOKUP函數(shù)是查找首次出現(xiàn)的值。

7.科目代碼跟科目名稱在同一個單元格如何分離？

針對Excel2013以下版本就比較麻煩，需要借助公式才可以。

科目代碼：

=LEFT(A2,2*LEN(A2)-LENB(A2))

科目名稱：

=RIGHT(A2,LENB(A2)-LEN(A2))

WPS表格新函數(shù)。

=REGEXP(A2,"[0-9]+")

=REGEXP(A2,"[一-龜]+")

針對高版本，這種問題就顯得非常簡單，借助新功能快速填充，快捷鍵Ctrl+E，就可以實現(xiàn)。

8.將B列的金額依次拆分到后面的單元格

=LEFT(RIGHT(TEXT($B2*100," ￥000;;"),COLUMNS(F:$P)))

9.將金額轉換成人民幣大寫

=SUBSTITUTE(SUBSTITUTE(TEXT(TRUNC(FIXED(J12)),"[>0][dbnum2]G/通用格式元;[<0]負[dbnum2]G/通用格式元;;")&TEXT(RIGHT(FIXED(J12),2),"[dbnum2]0角0分;;"&IF(ABS(J12)>1%,"整",)),"零角",IF(ABS(J12)<1,,"零")),"零分","整")

WPS設置單元格格式，特殊，人民幣大寫，這樣就不用謝復雜的公式。