這組函數(shù)的功能是在主圖或副圖上設(shè)定條件輸出圖象、圖標(biāo)、直線、文字、數(shù)字、指標(biāo)線、指標(biāo)柱等，全部可以單獨(dú)使用。

個(gè)人感覺(jué)，飛狐的強(qiáng)大功能，在此組函數(shù)中有淋漓盡致的發(fā)揮。無(wú)論在表面（美感），還是實(shí)質(zhì)（提高工作效率）上，都有良好表現(xiàn)。

毫無(wú)例外的是，這組函數(shù)中，都帶有COND。CONDITION，條件，狀態(tài)。COND在這里可作為條件理解。

為了能找到合適的COND，用于舉例子，請(qǐng)?jiān)试S我先介紹一組概念。

高點(diǎn)：在2N+1根K線中，中間這根K線的H，要大于等于左右N根K線的H。在N+1根K線中，有等高點(diǎn)出現(xiàn)，取最先出現(xiàn)的。

低點(diǎn)：在2N+1根K線中，中間這根K線的L，要小于等于左右N根K線的L。在N+1根K線中，有等低點(diǎn)出現(xiàn)，取最先出現(xiàn)的。

峰點(diǎn)：高點(diǎn)和低點(diǎn)，合稱為峰點(diǎn)。

（這個(gè)定義，意合于技術(shù)分析的老祖宗道氏：“只要平均指數(shù)的最高點(diǎn)超過(guò)了前期的最高點(diǎn)，它就處于牛市時(shí)期；當(dāng)最低點(diǎn)低于前期的最低點(diǎn)時(shí)，它處于熊市時(shí)期。”這里我們撇開(kāi)向上、向下分形和分形峰狀點(diǎn)等概念，以免把概念復(fù)雜化。）

也為了不讓公式一來(lái)就過(guò)于復(fù)雜，我們先取N為2來(lái)做公式。簡(jiǎn)介到后面，可以看到，N是可以作為峰點(diǎn)公式的參數(shù)進(jìn)行調(diào)整的。

公式名稱：FENG2

公式說(shuō)明：供引用

公式內(nèi)容：

{峰點(diǎn)參數(shù)暫定為2}

A:=REF(H,2);{中間K線的最高價(jià)}

B:=A>=REF(H,4) AND A>=REF(H,3) AND A>=REF(H,1) AND A>=H;{中間K線的最高價(jià)大于等于兩邊共四根K線的最高價(jià)}

D:=BACKSET(B,3);{將當(dāng)前位置和之前2個(gè)周期的數(shù)值設(shè)為1}

HD:FILTER(D,2);{找到高點(diǎn)后，過(guò)濾掉其后2周期內(nèi)可能出現(xiàn)的等高點(diǎn)。輸出高點(diǎn)}

A2:=REF(L,2);{中間K線的最低價(jià)}

B2:=A2<=REF(L,4) AND A2<=REF(L,3) AND A2<=REF(L,1) AND A2<=L;{中間K線的最低價(jià)小于等于兩邊共四根K線的最低價(jià)}

D2:=BACKSET(B2,3);{將當(dāng)前位置和之前2個(gè)周期的數(shù)值設(shè)為1}

LD:FILTER(D2,2);{找到低點(diǎn)后，過(guò)濾掉其后2周期內(nèi)可能出現(xiàn)的等低點(diǎn)。輸出低點(diǎn)}

{后面有些例子，就從這個(gè)公式中引用信號(hào)。}

一、

函數(shù)： DRAWICON

參數(shù)： 無(wú)

用法： DRAWICON(COND,PRICE,TYPE),當(dāng)COND條件滿足時(shí),在PRICE位置畫(huà)TYPE號(hào)圖標(biāo)。

說(shuō)明： 在圖形上繪制小圖標(biāo)，其中TYPE可選7種圖標(biāo),編碼為1-7（1-3為小臉，4、5為上下箭頭，6、7為紅綠小旗）。TYPE為　　　 字符串時(shí)可顯示用戶自制BMP圖。

示例： DRAWICON(CLOSE>OPEN,LOW,1)；表示當(dāng)收陽(yáng)時(shí)在最低價(jià)位置畫(huà)1號(hào)圖

　　　 DRAWICON(C>O,L,'MyBMP')表示當(dāng)收陽(yáng)時(shí)在最低價(jià)位置畫(huà)FmlDLL子目錄下的自制圖標(biāo)MyBMP.BMP


1、COND條件，一般是指判斷的結(jié)果，不是0就是1。如用其它數(shù)據(jù)，大于等于1的，條件滿足；小于1，條件就不滿足。

2、TYPE圖標(biāo)，現(xiàn)在已經(jīng)有12種，用下面的公式，在000829上可以全部顯示出來(lái)。當(dāng)TYPE取大于等于12的數(shù)時(shí)，都顯示黃球。

當(dāng)TYPE取0時(shí)，顯示的是笑臉（這個(gè)公式中沒(méi)有做進(jìn)去，自己可以試一下）。

B:="FENG2.HD";

D:=BACKSET(ISLASTPERIOD,BARSLAST(B)+1);

A:=D>REF(D,1);

DRAWICON(REF(A,1),1.05*H,1);

DRAWICON(REF(A,2),1.05*H,2);

DRAWICON(REF(A,3),1.05*H,3);

DRAWICON(REF(A,4),1.05*H,4);

DRAWICON(REF(A,5),1.05*H,5);

DRAWICON(REF(A,6),1.05*H,6);

DRAWICON(REF(A,7),1.05*H,7);

DRAWICON(REF(A,8),1.05*H,8);

DRAWICON(REF(A,9),1.05*H,9);

DRAWICON(REF(A,10),1.05*H,10);

DRAWICON(REF(A,11),1.05*H,11);

DRAWICON(REF(A,12),1.05*H,12);

DRAWICON(REF(A,13),1.05*H,13);

DRAWICON(REF(A,14),1.05*H,100);{主圖疊加}

當(dāng)紅球和綠球連續(xù)顯示時(shí)，立體感會(huì)強(qiáng)一些。

DRAWICON(C>=MA(C,30),MA(C,30),10);

DRAWICON(C<MA(C,30),MA(C,30),11);{主圖疊加}

3、PRICE是用于定位圖標(biāo)的位置的。一般用1.01＊H，或者0.99*L等?，F(xiàn)在可用ALIGN(0-5)指定對(duì)齊位置。

用這個(gè)公式來(lái)試（主圖疊加）

B:="FENG2.HD";

D:=BACKSET(ISLASTPERIOD,BARSLAST(B)+1);

A:=D>REF(D,1);

E:=REF(H,1);

DRAWICON(A,E,10),ALIGN0;

DRAWICON(A,E,11),ALIGN1;

DRAWICON(A,E,12),ALIGN2;

DRAWICON(A,E,3),ALIGN3;

DRAWICON(A,E,4),ALIGN4;

DRAWICON(A,E,5),ALIGN5;

可以初步得出結(jié)論：

ALIGN0：信號(hào)出現(xiàn)在PRICE的正中；

ALIGN1：信號(hào)出現(xiàn)在PRICE下邊（十分靠近）；

ALIGN2：信號(hào)出現(xiàn)在PRICE上邊（十分靠近）；

ALIGN3：信號(hào)出現(xiàn)在主圖的中間；

ALIGN4：信號(hào)出現(xiàn)在主圖的最上邊；

ALIGN5：信號(hào)出現(xiàn)在主圖的最下邊；

在高低點(diǎn)上作圖標(biāo)，可以使高低點(diǎn)更明確了。

A:="FENG2.LD";

B:="FENG2.HD";

DRAWICON(A,L,11),ALIGN1;

DRAWICON(B,H,10),ALIGN2;{主圖疊加}



4、可以自由調(diào)用MyBMP.BMP圖到顯示位置，大大增強(qiáng)了輸出的效果。你只要看到好看的圖，可以隨時(shí)抓拍過(guò)來(lái)，做成BMP文件，放到FmlDLL子目錄下，就可以調(diào)用了。

A:="FENG2.LD";

B:="FENG2.HD";

DRAWICON(A,L,'PIG'),ALIGN1;

DRAWICON(B,H,'PIG'),ALIGN2;{主圖疊加。如果你沒(méi)有PIG.BMP文件，則不可顯示。}



DRAWICON(1,MA(C,5),'S28');

DRAWICON(1,MA(C,10),'S31');

DRAWICON(1,MA(C,20),'S14');

DRAWICON(1,MA(C,30),'S25');{主圖疊加。如果你想要這個(gè)公式有顯示，可到樓下下載，解壓縮到FmlDLL子目錄下}



內(nèi)有40個(gè)不同顏色的小球。

二、

函數(shù)： DRAWLINE

參數(shù)： 無(wú)

用法： DRAWLINE(COND1,PRICE1,COND2,PRICE2,EXPAND),當(dāng)COND1條件滿足時(shí),在PRICE1位置畫(huà)直線起點(diǎn)，當(dāng)COND2條件滿足時(shí),在PRICE2位置畫(huà)直線終點(diǎn)，EXPAND為延長(zhǎng)類(lèi)型。  

說(shuō)明： 在圖形上繪制直線段。

示例： DRAWILINE(HIGH>=HHV(HIGH,20),HIGH,LOW<=LLV(LOW,20),LOW,1)；表示在創(chuàng)20天新高與創(chuàng)20天新低之間畫(huà)直線并且向右延長(zhǎng)。

DRAWLINE是唯一一個(gè)一句里面用到兩個(gè)COND的繪圖函數(shù)。因?yàn)樗枰獌蓚€(gè)點(diǎn)來(lái)決定一直線。

COND1相當(dāng)于指定K線位置（橫坐標(biāo)），PRICE1相當(dāng)于是指定價(jià)位（縱坐標(biāo)），這樣一個(gè)點(diǎn)在平面上的位置就決定了。

DRAWLINE是從第一點(diǎn)畫(huà)到第二點(diǎn)的，即有起點(diǎn)與終點(diǎn)的順序關(guān)系：第一點(diǎn)出現(xiàn)的時(shí)間，要在第二點(diǎn)之前。否則線是畫(huà)不出來(lái)的。

EXPAND，擴(kuò)張、發(fā)展，這里是延伸的意思吧。一般取0，不延長(zhǎng)；取1，延長(zhǎng)。實(shí)際上是取大于等于1的數(shù)就延長(zhǎng)，小于1就不延長(zhǎng)。

DRAWLINE目前支持POINTDOT、LINETHICK、COLOR、SHIFT這四個(gè)描述函數(shù)。

舉個(gè)例子吧。

A:="FENG2.LD";

B:="FENG2.HD";

DRAWICON(A,L,11),ALIGN1;

DRAWICON(B,H,10),ALIGN2;

D:=BACKSET(ISLASTPERIOD,BARSLAST(B)+1);

E:=D>REF(D,1);

F:=BACKSET(E,REF(BARSLAST(B),1)+2);

G:=F>REF(F,1);

DRAWLINE(G,H,E,H,1),pointdot,linethick1,coloryellow;{主圖疊加}



這根線有些趨勢(shì)線的意思了。由于趨勢(shì)線的主觀性頗強(qiáng)，只有多設(shè)參數(shù)才能滿足多數(shù)人的要求，以后有機(jī)會(huì)再作介紹。

DRAWLINE畫(huà)出的線，應(yīng)該比手工畫(huà)出的線精確一些。（DRAWLINE畫(huà)線的靈敏度，要比手工畫(huà)線低，所以說(shuō)DRAWLINE畫(huà)出的線精確，就未必對(duì)。）

主要用于畫(huà)斜線，水平線我們一般可以另想辦法。因?yàn)樵趫D中顯示直線，并非DRAWLINE的“專(zhuān)利”。

比如：

A:="FENG2.LD";

B:="FENG2.HD";

D:=BACKSET(ISLASTPERIOD,BARSLAST(A)+1);

E:=D>REF(D,1);

F:=BACKSET(ISLASTPERIOD,BARSLAST(B)+1);

G:=F>REF(F,1);

前高:REF(H,BARSLAST(G));

前低:REF(L,BARSLAST(E));{主圖疊加}



這里出個(gè)“難題”吧：

怎么在主圖上畫(huà)一根直線？直線的高度是今天收盤(pán)價(jià)。就是這個(gè)樣子的：



三、

函數(shù)： DRAWTEXT

參數(shù)： 無(wú)

用法： DRAWTEXT(COND,PRICE,TEXT),當(dāng)COND條件滿足時(shí),在PRICE位置書(shū)寫(xiě)文字TEXT,可顯示多行文本，用"\n"換行。

說(shuō)明： 在圖形上顯示文字。

示例： DRAWTEXT(CLOSE/OPEN>1.08,LOW,'大陽(yáng)線')；表示當(dāng)日漲幅大于8%時(shí)在最低價(jià)位置顯示'大陽(yáng)線'字樣。

DRAWTEXT(CLOSE/OPEN>1.08,LOW,'好呀\n大漲啦')；可顯示多行文本，用"\n"換行；

在某些滿足條件的地方直接顯示文字或字符，比顯示圖標(biāo)要更直觀一些。

此函數(shù)可以用ALIGN來(lái)定位水平位置。而ALIGN用在DRAWICON上定位的是高低的位置。

從下面例子可以看到，ALIGN(0~2)定義水平位置的意義：

ALIGN0：居中；

ALIGN1：偏右；

ALIGN2：偏左。

也可以用SHIFT函數(shù)進(jìn)行向右水平移位。

所顯示的文字或字符，可以用COLOR函數(shù)來(lái)定義顏色。至于文字的大小，則采用系統(tǒng)默認(rèn)的大小，在此函數(shù)中無(wú)法定義。

此函數(shù)單獨(dú)使用有其用途，與DRAWNUMBER配合應(yīng)用時(shí)，效果更不錯(cuò)。后面介紹到DRAWNUMBER時(shí)再舉例子。

A:="FENG2.LD";

B:="FENG2.HD";

DRAWICON(A,L,11),ALIGN1;

DRAWICON(B,H,10),ALIGN2;

D1:=BACKSET(ISLASTPERIOD,BARSLAST(B)+1);

E1:=D1>REF(D1,1);{離目前最近的一個(gè)高點(diǎn)}

D2:=BACKSET(E1,REF(BARSLAST(B),1)+2);

E2:=D2>REF(D2,1);{倒數(shù)第二個(gè)高點(diǎn)}

D3:=BACKSET(E2,REF(BARSLAST(B),1)+2);

E3:=D3>REF(D3,1);{倒數(shù)第三個(gè)高點(diǎn)}

DRAWTEXT(E1,H*1.01,'☆TEXT:'),COLORRED,ALIGN0;

DRAWTEXT(E2,H*1.01,'★TEXT:'),COLORGREEN,ALIGN1;

DRAWTEXT(E3,H*1.01,'▓TEXT:'),COLORYELLOW,ALIGN2;{主圖疊加}



四、

函數(shù)： POLYLINE

參數(shù)： 無(wú)

用法： POLYLINE(COND,PRICE),當(dāng)COND條件滿足時(shí),以PRICE位置為頂點(diǎn)畫(huà)折線連接。

說(shuō)明： 在圖形上繪制折線段。

示例： POLYLINE(HIGH>=HHV(HIGH,20),HIGH)；表示在創(chuàng)20天新高點(diǎn)之間畫(huà)折線。

POLY，多個(gè)的。

支持POINTDOT、LINETHICK、COLOR、SHIFT這四個(gè)描述函數(shù)。

A:="FENG2.LD";

B:="FENG2.HD";

DRAWICON(A,L,11),ALIGN1;

DRAWICON(B,H,10),ALIGN2;

POLYLINE(A,L),POINTDOT,COLORGREEN;

POLYLINE(B,H),LINETHICK2,COLORMAGENTA;{主圖疊加}



五、

函數(shù)： STICKLINE

參數(shù)： 無(wú)

用法： STICKLINE(COND,PRICE1,PRICE2,WIDTH,EMPTY),當(dāng)COND條件滿足時(shí),在PRICE1和PRICE2位置之間畫(huà)柱狀線，寬度為WIDTH可為0---100(10為標(biāo)準(zhǔn)間距),EMPTH不為0則畫(huà)空心柱。

說(shuō)明： 在圖形上繪制柱線。  

示例： STICKLINE(CLOSE>OPEN,CLOSE,OPEN,0.8,1)；表示畫(huà)K線中陽(yáng)線的空心柱體部分。

再說(shuō)明三點(diǎn)：

1、PRICE1和PRICE2沒(méi)有順序關(guān)系，即何者在前何者在后都不影響語(yǔ)句的執(zhí)行。

2、WIDTH寬度，支持小數(shù)。用1和用0.1，會(huì)有很大的差別。取7時(shí)和主圖的K線寬度差不多。

以下的副圖公式，畫(huà)出的K線，與主圖中顯示的K線差不多。有些“主圖疊加公式”，疊加在副圖中也未嘗不可了。

STICKLINE(C>O OR (C=O AND C>REF(C,1)),O,C,7,1),colorred;{畫(huà)出紅K實(shí)體}

STICKLINE((C>O AND C<>H) OR (C=O AND C>REF(C,1)),C,H,0.1,0),colorred;{畫(huà)出紅K上影線}

STICKLINE((C>O AND L<>O) OR (C=O AND C>REF(C,1)),L,O,0.1,0),colorred;{畫(huà)出紅K下影線}

STICKLINE(C<O OR (C=O AND C<=REF(C,1)),C,O,7,0),colorcyan;{畫(huà)出青K實(shí)體}

STICKLINE(C<O OR (C=O AND C<=REF(C,1)),L,H,0.1,0),colorcyan;{畫(huà)出青K影線。因?yàn)榍郖是實(shí)心的，所以影線從中穿過(guò)}

MA(C,5);



3、用STICKLINE可以用兩種方法做出多色彩K線效果。

一種是橫向的，將K線實(shí)體從O到C分為N等份，每個(gè)小格中放入不同的但比較連續(xù)的顏色。

這里隨便舉個(gè)例子，N取4，只對(duì)陽(yáng)線加了效果。其它變化，道理是一樣的。

A:=C-O;

B:=C>O;

STICKLINE(B,O,O+A/4,8,0),COLORFF99FF;

STICKLINE(B,O+A/4,O+A*2/4,8,0),COLORFF00FF;

STICKLINE(B,O+A*2/4,O+A*3/4,8,0),COLOR9900FF;

STICKLINE(B,O+A*3/4,O+A,8,0),COLOR0000FF;{主圖疊加}



還有一種方法就是縱向的了。先在較寬的K線中加顏色，然后把寬度逐步收窄，再加顏色覆蓋以前的的，這樣從縱向看，一根K線中就有不同顏色了。效果做得好的，可以做到賞心悅目。

B:=C>O;

STICKLINE(B,O,C,8,0),COLORFF99FF;

STICKLINE(B,O,C,6,0),COLORFF00FF;

STICKLINE(B,O,C,4,0),COLOR9900FF;

STICKLINE(B,O,C,2,0),COLOR0000FF;{主圖疊加}



六、

函數(shù)： DRAWNUMBER(COND,PRICE,NUMBER,PRECISION)

參數(shù)： NUMBER（可以為常數(shù)或數(shù)組序列）,PRECISION為精度(取值范圍0-3),即顯示到小數(shù)點(diǎn)后PRECISION位。

用法： DRAWNUMBER(COND,PRICE,NUMBER,PRECISION),當(dāng)COND條件滿足時(shí),在PRICE位置書(shū)寫(xiě)數(shù)字

說(shuō)明： 在圖形上顯示數(shù)字。

示例： DRAWNUMBER(CLOSE/OPEN>1.08,HIGH,(CLOSE-OPEN)/OPEN*100,2)；表示當(dāng)日漲幅大于8%時(shí)在最低價(jià)位置顯示漲幅(相對(duì)開(kāi)盤(pán)價(jià)的百分比)。

這個(gè)函數(shù)的特色是，在NUMBER位置可以放變量。

NUMBER,數(shù)字。DRAWNUMBER是DRAWTEXT的“兄弟”，也可以用ALIGN(0~2)來(lái)定義水平位置，方法相同。

A:="FENG2.LD";

B:="FENG2.HD";

DRAWICON(A,L,11),ALIGN1;

DRAWICON(B,H,10),ALIGN2;

D1:=BACKSET(ISLASTPERIOD,BARSLAST(B)+1);

E1:=D1>REF(D1,1);{離目前最近的一個(gè)高點(diǎn)}

D2:=BACKSET(E1,REF(BARSLAST(B),1)+2);

E2:=D2>REF(D2,1);{倒數(shù)第二個(gè)高點(diǎn)}

DRAWTEXT(E1,H*1.02,'高點(diǎn)價(jià)：'),COLORGREEN,ALIGN2;

DRAWNUMBER(E1,H*1.02,H,2),COLORGREEN,ALIGN1;

DRAWTEXT(E2,H*1.02,'高點(diǎn)價(jià)：'),COLORYELLOW,ALIGN2;

DRAWNUMBER(E2,H*1.02,H,2),COLORYELLOW,ALIGN1;{主圖疊加}



七、

函數(shù)： FILLRGN(COND,PRICE1,PRICE2)

參數(shù)：   

用法： FILLRGN(COND,PRICE1,PRICE2),當(dāng)COND條件滿足時(shí),以COLOR填充PRICE1和PRICE2的區(qū)間

說(shuō)明： 繪制指標(biāo)區(qū)間彩帶。

示例： FILLRGN(MA1>MA2, MA1,MA2),colorred； 表示MA1>MA2時(shí)以紅色填充MA1和MA2之間的區(qū)域。

FILL，充滿，填充。RGN可能是REGION，地區(qū)，地域。

用這個(gè)函數(shù)，再加DRAWICON可以調(diào)用BMP圖象文件的功能，可以作出象風(fēng)景一樣的圖。

這里舉個(gè)簡(jiǎn)單的例子：

A:=MA(C,5);

B:=MA(C,10);

FILLRGN(1,H*1.01,H*1.02),COLORFFFF66;

FILLRGN(A>=B,A,B),COLORMAGENTA;

FILLRGN(A<B,A,B),COLORGREEN;

FILLRGN(1,L*0.99,L*0.98),COLORFF99CC;{主圖疊加}

416

八、

函數(shù)： PARTLINE(COND,PRICE)

參數(shù)：   

用法： PARTLINE(COND,PRICE),滿足COND條件繪制PRICE連線。

說(shuō)明： 分段繪制指標(biāo)線

示例： PARTLINE(C>REF(C,1),C),colorred；表示收盤(pán)大于前收以紅色繪制收盤(pán)價(jià)連線。

PART，部分，局部。值得一提的是，PARTLINE支持多種描述函數(shù)，如例所見(jiàn)。

A:=MA(C,5);

B:=MA(C,10);

PARTLINE(A>=B,A),COLORRED,POINTDOT;

PARTLINE(A>=B,B),COLORGREEN,CIRCLEDOT;

PARTLINE(A<B,A),COLORGREEN,CROSSDOT,LINETHICK3;

PARTLINE(A<B,B),COLORRED,SHIFT2;{主圖疊加}



九、

函數(shù)： VERTLINE(COND)

參數(shù)：   

用法： VERTLINE(COND),在COND條件滿足的周期處畫(huà)垂直線

說(shuō)明： 在圖形上繪制垂直線段

示例： DVERTLINE(HIGH>=HHV(HIGH,20)；表示在創(chuàng)20天新高時(shí)畫(huà)垂直線

VERTICAL，垂直的。

VERTLINE目前可以用POINTDOT、LINETHICK、COLOR、SHIFT這四個(gè)描述函數(shù)來(lái)描述。

這個(gè)函數(shù)，主要是用于畫(huà)線看時(shí)間的。費(fèi)波納契周期，可以用這個(gè)函數(shù)畫(huà)出來(lái)的。

這里舉個(gè)例子，把日K線中每月的第一個(gè)交易日中，畫(huà)一根垂直線。

A:=MONTH>REF(MONTH,1);

VERTLINE(A),COLOR808040,POINTDOT;{主圖疊加}



十、

函數(shù)： DRAWYITEXT(COND,PRICE,CODE,TYPE)

參數(shù)：        

用法： 在COND在圖形上顯示易學(xué)文字,可ALIGN0-3定義對(duì)齊方式。

說(shuō)明： 當(dāng)COND條件滿足時(shí),在PRICE位置書(shū)寫(xiě)TYPE類(lèi)型的CODE的對(duì)應(yīng)文字
TYPE為常數(shù)，取0--1，分別表示計(jì)算的是干支、64卦，CODE為對(duì)應(yīng)的代碼



示例： DRAWYITEXT(CLOSE/OPEN>1.05,LOW, GANZHI(DATE*100, 2),0)，表示當(dāng)日漲幅大于5%時(shí)在最低價(jià)位置顯示日干支；
DRAWYITEXT(REF(CLOSE,2)>REF(OPEN,2) AND REF(CLOSE,1)>REF(OPEN,1) AND CLOSE>OPEN, LOW, KGUA(1, 1), 1 )，表示連二陽(yáng)時(shí)在最低價(jià)位置顯示K線卦象。

如下例子：K線卦

kk:=KGUA(0,6);
DRAWYITEXT(c>0,mod(BARSCOUNT(c),6),kk,1); {附圖指標(biāo)}



十一、

函數(shù)： DRAWBKBMP(COND,BMP)

參數(shù)：        

用法: 當(dāng)圖形上最后一組COND條件滿足時(shí),以MyBMP做背景：        

說(shuō)明： 根據(jù)條件設(shè)置背景圖

示例： 因?yàn)橄到y(tǒng)K線先畫(huà)，會(huì)被后來(lái)的指標(biāo)圖覆蓋了

這種公式K線要自己畫(huà)，以下供參考


DRAWBKBMP(c>0,'mybmp');
STICKLINE(c>o or c=o and c>ref(c,1),l,h,0.1,0),colorred;
STICKLINE(c>o or c=o and c>ref(c,1),o,c,7,0),colorred;

STICKLINE(c<o or c=o and c<=ref(c,1),l,h,0.1,0),colorcyan;
STICKLINE(c<o or c=o and c<=ref(c,1),o,c,7,0),colorcyan;

把公式設(shè)為主圖、主圖疊加



十二、

函數(shù)： DRAWGBK(COND,COLOR1, COLOR2,D)

參數(shù)：   

用法： 當(dāng)COND條件滿足時(shí),以COLOR1到COLOR2漸變色填充子圖區(qū)域,D=0表示從左到右,D=1表示從上到下

說(shuō)明： 繪制漸變背景色

示例： DRAWGBK(C>O, COLORRGB(255,0,0), COLORRGB(255,255,0),0);
表示圖形上最后一組C>O時(shí)從左到右從紅色到黃色漸變填充子圖。

 

飛狐基本函數(shù)簡(jiǎn)介之時(shí)間函數(shù)

飛狐基本函數(shù)簡(jiǎn)介之引用函數(shù)